gokhanca.com

1. Bütün takımlar büyük puandan küçük puana doÄŸru sıralanır.
    
2. EÄŸer aynı puana sahip takımlar varsa bunlar kendi aralarında oynadıkları maçlardaki puan üstünlüÄŸüne göre yerleÅŸir.
    
3. Kendi aralarındaki maçlarda puan eÅŸitliÄŸi varsa kendi aralarında oynadıkları maçlardaki gol averajına göre yerleÅŸir. EÄŸer kendi aralarındaki maçlarda atılan gollerde eÅŸitlik var ise deplasmanda fazla gol atan takım üstün sayılmaz.
    
4. Kendi aralarındaki maçlarda puan ve gol eÅŸitliÄŸi devam ediyorsa, genel puantajdaki gol averajına bakılır.
    
5. Takımlar arasındaki gol averajı da eÅŸit ise genel toplamda daha fazla gol atmış olan takım üstün sayılır.
    
6. Bu ÅŸartlara raÄŸmen eÅŸitlik devam ediyorsa hükmen yenilgisi olmayan takım üstün sayılır.
    
7. Bütün bu ÅŸartlara raÄŸmen eÅŸitliÄŸin devam etmesi halinde ilgili takımlar arasında yapılacak tek maçlar neticesinde kazanan takım üstün sayılarak nihai sonuç alınır. Yani, bir A takımı ile bir B takımı sadece 1 maç yapar. Maçlar denmesinin sebebi aynı anda 2'den fazla takım olması durumudur.

DÄ°ZÄ° TANIMLAMAK

Şimdi aklımıza hemen bir dizi oluşturmak gelmiş olabilir. Diziyi aşağıdaki gibi tanımlayalım.

Dim Takim(1 to 18) As String
Dim Puan(1 to 18) As Integer
Dim Oynadigi(1 to 18) As Integer
Dim Attigi(1 to 18) As Integer

Genelde ilk akla gelen uygulama budur. Her özellik için ayrı bir dizi oluÅŸturulur ve aynı indisli veriler aynı takıma ait olan verilerdir. Örnek:

'5 nolu takım bilgileri
Takim(5) = "Galatasaray"
Puan(5) = 28
Oynadigi(5) = 16
Attigi(5) = 20

Bu ÅŸekildeki bir mantık doÄŸrudur fakat çok hantaldır. Özellikle sıralama iÅŸlerinde diziler karışır ve gereksizce fazla kod yazılır. Kodların takibi ve düzeni arapsaçı gibi olur. ÇoÄŸu kiÅŸinin hata yaptığı nokta doÄŸru dizi mantığı kuramamaktadır. Åžimdi bu iÅŸ için örnek bir dizi tanımı yapalım. TYPE yapısı oluÅŸturarak birden çok deÄŸiÅŸkeni tek bir özellik altında gruplayabiliriz. Bu sayede bir nesnenin özelliklerini oluÅŸturmuÅŸ oluruz.

' Dizi için özel deÄŸiÅŸken tipi tanımlanıyor
Type TakimOzellik
    Index As Integer
    isim As String
    Oynanan As Integer
    Galibiyet As Integer
    Beraberlik As Integer
    Maglubiyet As Integer
    Attigi As Integer
    Yedigi As Integer
    Puan As Integer
    HukmenMaglubiyet As Integer
    ikilipuan As Integer   ' Ä°kili sınama durumunda puan
    ikiligol As Integer    ' ikili sınama durumunda gol sayısı
End Type

Bir tanesi yedek olmak üzere 19 takım tanımlanır.
Public Takim(1 To 19) As TakimOzellik

Bu sayede tek bir diziye deÄŸiÅŸik özellikler eklemiÅŸ olduk. Artık bu diziyi bir nesne gibi kullanabiliriz. Yukarıdaki kodları proje içerisinde bir module içine yazın. Böylece tüm proje içerisinde kullanabilirsiniz. Takim dizisine nasıl bir özellik kattığımızı aÅŸağıda görebilirsiniz.

Artık dizimiz tek bir isim altında deÄŸiÅŸik özelliklere sahip olarak oluÅŸturuldu. Yani nesne modelli programlamanın bir avantajını kullanmış olduk. Program baÅŸlarken sadece Erase Takim komutunu kullanarak diziyi resetleyebilir. Daha sonra istediÄŸiniz bir yöntemle takimlar hakkındaki bilgileri Takim dizisi içerisine yazabilirsiniz. Bu konuda istediÄŸiniz uygulamayı yapabilirsiniz. Ben örnek programımda bir text dosya içerisine maç skorlarını yazdırıp yine aynı dosyadan gerekli bilgileri okutturdum. Ä°steyen veritabanı da kullanabilir.

SIRALAMA MANTIÄžI 

Futbol kurallarına göre bir algoritmik akış ÅŸeması oluÅŸturalım. Akış ÅŸeması biraz uzun olduÄŸu için Burayı Tıklatarak ayrı bir pencerede algoritmasını görebilirsiniz. Sıralama iÅŸlemi için birkaç sub programı tanımlayalım. Bunlar bizi her defasında benzer kodları yazma derdinden kurtaracak. Aynı zamanda daha anlaşılabilir bir kod düzeni saÄŸlayacak. Ä°lk Sub'ımız a ve b indisli takımları yer deÄŸiÅŸtirmekle ilgili.

Public Sub TakimDegistir(a, b)
    ' indexi a ve b olan iki takım yer deÄŸiÅŸtirilir.
    ' takim(19) boÅŸ olan takımdır. DeÄŸiÅŸtirme iÅŸlemi için kullanılır.
    Takim(19) = Takim(a)
    Takim(a) = Takim(b)
    Takim(b) = Takim(19)
End Sub

GördüÄŸünüz gibi a ve b indisli takımları yer deÄŸiÅŸtirmek ne kadar kolay. EÄŸer bir sürü dizi tanımlasaydık gereksizce fazladan kod yazacaktık. Devam edelim. EÄŸer proje içerisinde tablo olarak MSHFlexGrid kullanacaksanız aÅŸağıdaki kod iÅŸinize yarayacaktır. Bu kod modül içerisindedir ve anaform adlı form üzerinde bulunan bir MSHFlexGrid nesnesine deÄŸer yazar. Obje deÄŸeri için anaformdaki MSHFlexGrid nesnesinin adını yazmalısınız. Bunun kullanılmasının anlamı, anaform üzerinde birden fazla MSHFlexGrid kullanıyorsanız nesne ismini yollayıp istediÄŸiniz tabloya yazdırma iÅŸlemi yaptırabilmenizdir.

Public Sub TabloyaYaz(satir, sutun, yazi As String, obje As MSHFlexGrid)
    ' Satir ve Sutun kooordinatlarındaki hücreye Yazi deÄŸerini yazar.
    With anaform
        obje.Col = sutun
        obje.Row = satir
        obje.Text = yazi
    End With
End Sub

' Örnek Kullanım
TabloyaYaz 4,3,"Fenerbahçe", PuanTablosu
TabloyaYaz 1,3,"Galatasaray", PuanTablosu
TabloyaYaz 2,2,"BeÅŸiktaÅŸ", MaclarTablosu

Bu Sub ise seçilen bir takıma puan vermek için kullanılır. Özellikle maçların sonuçlarını deÄŸerlendirirken iÅŸinize yarayacaktır.

Sub PuanVer(TakimAdi As String, Puan As Integer, Att As Integer, Yed As Integer)
      
' Takımın Adına Göre Dizi Taranır. Bulunan Yerde DeÄŸiÅŸiklikler Ä°ÅŸlenir.
    For i = 1 To 18
       
        If Takim(i).isim = TakimAdi Then
           
            Takim(i).Attigi = Takim(i).Attigi + Att
            Takim(i).Yedigi = Takim(i).Yedigi + Yed
            Takim(i).Puan = Takim(i).Puan + Puan
           
            Select Case Puan
                Case 1: Takim(i).Beraberlik = Takim(i).Beraberlik + 1
                Case 3: Takim(i).Galibiyet = Takim(i).Galibiyet + 1
                Case 0: Takim(i).Maglubiyet = Takim(i).Maglubiyet + 1
            End Select
           
            Takim(i).Oynanan = Takim(i).Oynanan + 1
            Exit For

        End If
    Next

End Sub

' Örnek Kullanım-1 : Galatasaray, GençlerbirliÄŸi'ni  4-1 yendiyse

PuanVer "Galatasaray" , 3 , 4 , 1
PuanVer "GençlerbirliÄŸi" , 0 , 1 , 4

Örnek Kullanım-2 : Real Madrid, Barcelona 2-2 berabere kaldıysa

PuanVer "Real Madrid", 1 , 2 , 2
PuanVer "Barcelona", 1 , 2 , 2

Yukarıdaki 3 Sub program ile birçok iÅŸi zahmetsizce yapabiliriz. Åžimdi sıralamaya geçelim. Bir Command butona bastığımızda sıralama iÅŸlemi baÅŸlamış olsun. AÅŸağıdaki kodları bir Command butonun Click yordamına yazın.

For i = 1 To 17
    For j = i + 1 To 18

        ' i. ve j. takımların puanları kontrol edilir.
        If Takim(i).Puan < Takim(j).Puan Then   ' Puan ÜstünlüÄŸü Durumu

            TakimDegistir i, j

        ElseIf Takim(i).Puan = Takim(j).Puan Then   ' Puan EÅŸitliÄŸi Varsa

            KendiMaclari i, j

        End If
       
    Next
Next

Ä°ÅŸte bütün sıralama iÅŸlemi bu kadar. Burada kullanılan sıralama algoritması EXCHANGE SORT (YerdeÄŸiÅŸtirme Sıralaması) olarak bilinen algoritmadır. EÄŸer dikkat ettiyseniz, "Sıralamada alttaki takımın puanı, Üstteki takımın puanından büyükse deÄŸiÅŸiklik yap" diye bir kontrol var. Sadece bu kontrol bize yeter. Çünkü üstteki takımın puanı büyükse zaten yer deÄŸiÅŸtirmeye gerek yoktur. Bir de puan eÅŸitliÄŸi olayı var. EÄŸer seçilen 2 takımın puanı eÅŸitse, konunun en başında anlattığım futbol ligi sıralama kurallarına göre tek tek kontrol yapılması gerekir. Bu kontroller KendiMaclari adlı Sub program içerisinde yapılmaktadır. Ä°ÅŸte bütün olayı  gerçekleÅŸtiren ana sub programı burası.

Sub KendiMaclari(a, b)

   ' Bu kısımda takımların kendi aralarında oynadıkları maçlara bakılarak
   ' Ä°kiliGol ve Ä°kiliPuan deÄŸerleri hesaplanır. Ben bu kısımdaki kodları yazmadım
   ' Siz kendinize uygun iÅŸlemle bu bilgileri derleyin.
   ' ---------------------------   

   ' AÇIKLAMA : a indexi her zaman b indexinden küçüktür.
   ' a takımının ikili puanı b takımından büyükse yer deÄŸiÅŸtirmeye gerek yoktur.
           
    If Takim(a).ikilipuan < Takim(b).ikilipuan Then
        TakimDegistir a, b
       
      ElseIf Takim(a).ikilipuan = Takim(b).ikilipuan Then
        ' Ä°kili Puan eÅŸitliÄŸi durumunda ikili Gollere bakılır.

        If Takim(a).ikiligol < Takim(b).ikiligol Then
            TakimDegistir a, b
           
          ElseIf Takim(a).ikiligol = Takim(b).ikiligol Then
            ' Ä°kili Goller de eÅŸit ise Genel Gol Averajına bakılır.

            If (Takim(a).Attigi - Takim(a).Yedigi) < (Takim(b).Attigi - Takim(b).Yedigi) Then
                TakimDegistir a, b

              ElseIf (Takim(a).Attigi - Takim(a).Yedigi) = (Takim(b).Attigi - Takim(b).Yedigi) Then
                ' Genel Gol Averajları da eÅŸitse toplamda fazla gol atan takıma bakılır

                If Takim(a).Attigi < Takim(b).Attigi Then
                    TakimDegistir a, b
               
                  ElseIf Takim(a).Attigi = Takim(b).Attigi Then
                   If Takim(b).HukmenMaglubiyet = 0 And Takim(a).HukmenMaglubiyet <> 0 Then
                        TakimDegistir a, b
                      Else
                        If Hafta = 36 Then
                      ' EÄŸer Ligin Son Haftasıysa :                                             ' Sıralamayı Belirleyecek Tek Maç Yapılır.
                      ' Bu maçta eÅŸitlik durumu olmayacaktır.
                      ' Beraberlik durumunda Penaltılar sonucu belirler.

                         End If
                    End If
                End If
            End If
        End If
    End If
End Sub

Bu hazır Sub programlarını, kendi programınız içerisinde kullanabilirsiniz. GörüldüÄŸü gibi TYPE yapısıyla doÄŸru ÅŸekilde dizi tanımlayınca iÅŸlemler çok basite indirgenmektedir. Programlarım sayfasından Futbol-Ligi adlı projeyi indirip kodlarda eksik kalan kısımlara bakabilirsiniz.